2.11 Single Dish VLBA Observing

SCHED is used primarily to schedule VLBI observations on the VLBA and most of the rest of this manual is devoted to details of how to do that. However, there are a variety of types of observations that are rather different. These are mainly single antenna observations usually done to measure system performance. SCHED is able to make the schedules for these observations. Such observations are not likely to be of interest to users other than NRAO staff involved in the testing and maintenance of the instrument.

Some items of special interest for VLBA scheduling are:

SOURCE: The source name is used in the usual way. However, for pointing, there is a useful capability to specify the name of a Solar System object and have SCHED determine its location from a JPL ephemeris. See the description of SOURCE for more details.

OBSTYPE: This should be set to NONE for single dish observations.

CALCODE: If set to “L”, pointing data will be processed using differences between the on-line and off-line channels.

PTVLBA: This can be specified on a scan basis and causes SCHED to write out a pointing pattern. It can be turned off with NOPTVLBA

TAVLBA: This can also be specific on a scan basis, but not for a scan with PTVLBA. It is another special mode, very similar to PTVLBA, for measuring antenna temperatures. It can be turned off with NOTAVLBA.

PN3DB: This can be specified on a scan basis and causes SCHED to write out half power tracking test pattern. It can be turned off with NOPN3DB

AZCOLIM: This specifies a pointing offset in arcminutes in the azimuth direction. It is equivalent to the term used in the pointing equations to account for feed offsets so it is a constant angle on the sky. The actual change in azimuth increases at high elevation because of the cos(El) dependence of the angular effect of an azimuth change. It is available both in the setup file and in the main schedule.

ELCOLIM: This specifies a pointing offset in arcminutes in the elevation direction. It is equivalent to the term used in the pointing equations to account for feed offsets and encoder offsets, which are equivalent for elevation. It is in the setup file.

PTINCR: This is the jump in arc minutes between the on-source and half-power pointing positions for use in setting up pointing patterns. It is used in PTVLBA, PN3DB and TAVLBA modes. This is a setup file parameter.

PTOFF: This is the jump in arc minutes between the on-source and off-source pointing positions for use in setting up pointing patterns. It is used in PTVLBA, PN3DB, and TAVLBA modes. The default is 6 times PTINCR. This is a setup file parameter.

PTDUR: This parameter is a time (in the usual time format) that specifies the time spent in each pointing position of a pointing pattern. A reasonable value is 15 seconds.

PTSLEW: This parameter specifies the time to allow to slew to the source. It is specified in the usual time units (seconds). With dwell time scheduling or schedule optimization, it should be kept small, often equal to PTDUR.

FOCUS: This is used to increment the subreflector focus position. The value is added to the nominal value known to the on-line system for the particular receiver.

ROTATION: This is used to increment the subreflector rotation position. The value is added to the nominal value known to the on-line system for the particular receiver.

ROTPAT: This triggers generation of a focus-rotation test pattern of pointing observations.

ROTOFF: This is used to specify the rotation offset positions of a focus-rotation pattern.

FOCOFF: This is used to specify the focus offset positions of a focus-rotation pattern.

EPHFILE: This is the name of the ephemeris file to use if planets are included in the pointing, as they typically are at high frequencies. At the AOC, the ephemeris files are typically kept in a directory assigned the environment variable PLANET_DATA. That assignment can depend on computer architecture because the files are binary.

There are a number of setup files among the standard setups that are for VLBA test observations. Those that start with pt are for pointing or antenna temperature observations. Those that start with pc are for pulse cal tests.

In addition to the above parameters, it is often best to make use of one of the optimization modes to make the actual schedules. OPTMODE=SCANS is perhaps the most useful. With this mode, only a few template scans need be specified and SCHED will pick the ones appropriate for use in the desired time range. Below is an example of a script, including everything necessary to run SCHED on each VLBA station, for making pointing and gain check observations. This example is at a somewhat higher level of complexity than most in this document, but it shows what can be done with the program. It actually makes a different schedule for each station, taking into account the different portions of the sky that can be seen.

#!/bin/csh  
#  
#  Try with VEX file  
#  
# ========================================================  
# =====  Script to make pointing files for the VLBA  =====  
# ========================================================  
#  Set stations to be processed.  
#  Note that the case used here will appear in the sum and  
#  vex file names, so it is better to use lower.  
#  The schedules need to be different depending on whether  
#  a 3mm receiver is present.  
#  Examples:  
#  set stalist_3mm="hn nl fd la pt kp ov mk"  
#  set stalist_no3mm="br sc"  
#  set stalist_no3mm=""      eg use blank if no stations of this type.  
set stalist_3mm="pt hn"  
set stalist_no3mm="hn"  
 
#  
#  Set times and experiment code  
#  
echo Sched environment variable = $SCHED  
echo PLANET_DATA environoment variable = $PLANET_DATA  
cat <<eofp >! times.par  
  year    = 1996  
  month   = 10  
  day     = 25  
  start   = 0:00:00  
  opdur   = 4:00:00         !  Total project duration  
eofp  
set  expcode="ptg"  
 
# =====================================================================  
# =====================================================================  
# ======                                                         ======  
# ======      Changes not normally needed below this line.       ======  
# ======                                                         ======  
# =====================================================================  
# =====================================================================  
# Specify the location of the setup files.  
#  
setenv SETDIR $SCHED/setups  
#  
# Put much of the generic setup information in ptg_setup.par  
#  
cat <<eofs >! ptg_setup.par  
! ---------------------------------------------------------------------  
! SCHED input file setup stuff to be used with pointing proceedure doptg.  
 
! -----  Cover information  
version  = 1  
expt     = ’STARTUP pointing’  
obstype  = PTVLBA  
obsmode  = ’Multi-frequency pointing observations.’  
piname   = ’Operations’  
phone    = ’505 835 7251’  
obsphone = ’505 835 7251’  
fax      = ’505 835 7027’  
email    = ’vlbaops@nrao.edu’  
address1 = ’AOC’  
 
! -----  Catalogs etc.  
srcfile = ’$SCHED/catalogs/sources.pointing’  
stafile = ’$SCHED/catalogs/stations.dat’  
ephfile = ’$PLANET_DATA/JPLEPH.405.2’  
!ephfile = ’$SCHED/catalogs/JPLEPH.405.2.Linux’  
! -----  Schedule instructions  
sumitem = EL1, AZ1 ! Start elevation and azimuth in summary.  
ptvlba  
ptdur   = 15       ! => scan length = ptslew + 2*ptdur + N*10*ptdur  
                   ! The autoleveling scan is 2*ptdur long for pcx.  
                   ! Here we have 15+30+2*150 = 345s = 5:45  
dwell   = 5:45  
ptslew  = 15  
optmode = SCANS    ! Select scans that are above minimum elevation.  
opminel = 20.      ! Minimum elevation.  
 
eofs  
 
#  Now make a file with the actual schedule info for 3mm sites.  
#  Any imbedded catalogs etc must be here.  
 
cat <<eofs >! ptg_3mm.par  
! -----  Spectral lines  
! -----  Set up for 4 channels - 2 on line, 2 off.  
lineinit /  
 lineset =’H2O’    restfreq=22235.08,22235.08,22285.08,22285.08 /  
 lineset =’SiO431’ restfreq=43122.03,43122.03,43222.03,43222.03 /  
 lineset =’SiO862’ restfreq=86243.4, 86243.4, 86343.4, 86343.4  /  
endlines /  
 
! -----  The detailed schedule  
! The frequencies are in an order reasonable for FRM.  
!  50/90 cm  CYGA,    TAUA,    3C274  
!  20-4 cm   3C454.3, 3C123,   3C274  
!  2, 1 cm   DR21,    3C84,    3C274  
!  7 mm      RCAS,    RLEO,    WHYA, DR21, 3C84, 3C273, planets  
!  3 mm      RCAS,    RLEO,    WHYA, planets  
 
!  Group must equal the number of scans below.  
!  (Group*rep) must be less than 2000 (as of 18 Apr 1996).  
!  The 7mm line sources used to have qual=50.  This used to be the way  
!     to trigger line processing.  Now CALCODE=’L’ does it.  
!  Note that for a peak=1 scan, no reference pointing will be done  
!  if the slew takes longer than 40 seconds.  That is partly why  
!  there is a second peak scan.  
 
 
group=(10*3+8*3) rep=50  
 
setup=’$SETDIR/pt90cm.set’  source ’CYGA’    nodop   bw=0,0   /  
setup=’$SETDIR/pt4cm.set’   source ’3C454.3’ nodop   bw=0,0   /  
setup=’$SETDIR/pt18cm.set’  source ’3C454.3’ nodop   bw=0,0   /  
setup=’$SETDIR/pt6cm.set’   source ’3C454.3’ nodop   bw=0,0   /  
setup=’$SETDIR/pt13cm.set’  source ’3C454.3’ nodop   bw=0,0   /  
setup=’$SETDIR/pt4cmsx.set’ source ’3C454.3’ nodop   bw=0,0   /  
setup=’$SETDIR/pt1cm.set’   source ’DR21’    nodop   bw=0,0   /  
setup=’$SETDIR/pt24ghz.set’ source ’DR21’    nodop   bw=0,0   /  
setup=’$SETDIR/pt2cm.set’   source ’DR21’    nodop   bw=0,0   /  
setup=’$SETDIR/pt7mm.set’   source ’DR21’    nodop   bw=0,0   /  
 
setup=’$SETDIR/pt7mm.set’   source ’JUPITER’ nodop   bw=0,0 qual=0  
  noptvlba peak=1 dwell=01:00  /  
  noptvlba peak=1 dwell=01:00  /  
  nopeak ptvlba   dwell = 5:45  /  
  setup=’$SETDIR/pt3mm.set’   nopeak ptvlba dwell = 5:45   /  
setup=’$SETDIR/pt7mm.set’   source ’RCAS’    doppler bw=2,2 qual=0  
  linename=’SiO431’  
  noptvlba peak=1 dwell=01:00  /  
  noptvlba peak=1 dwell=01:00  /  
  nopeak ptvlba   dwell = 5:45 /  
  setup=’$SETDIR/pt3mm.set’   nopeak ptvlba dwell = 5:45  linename=’SiO862’  /  
 
 
setup=’$SETDIR/pt90cm.set’  source ’TAUA’    nodop   bw=0,0   /  
setup=’$SETDIR/pt4cm.set’   source ’3C123’   nodop   bw=0,0   /  
setup=’$SETDIR/pt18cm.set’  source ’3C123’   nodop   bw=0,0   /  
setup=’$SETDIR/pt6cm.set’   source ’3C123’   nodop   bw=0,0   /  
setup=’$SETDIR/pt13cm.set’  source ’3C123’   nodop   bw=0,0   /  
setup=’$SETDIR/pt4cmsx.set’ source ’3C123’   nodop   bw=0,0   /  
setup=’$SETDIR/pt1cm.set’   source ’3C84’    nodop   bw=0,0   /  
setup=’$SETDIR/pt24ghz.set’ source ’3C84’    nodop   bw=0,0   /  
setup=’$SETDIR/pt2cm.set’   source ’3C84’    nodop   bw=0,0   /  
setup=’$SETDIR/pt7mm.set’   source ’3C84’    nodop   bw=0,0   /  
 
setup=’$SETDIR/pt7mm.set’   source ’RLEO’    doppler bw=2,2 qual=0  
  linename=’SiO431’  
  noptvlba peak=1 dwell=01:00  /  
  noptvlba peak=1 dwell=01:00  /  
  nopeak ptvlba   dwell = 5:45  /  
  setup=’$SETDIR/pt3mm.set’   nopeak ptvlba dwell = 5:45  linename=’SiO862’ /  
setup=’$SETDIR/pt7mm.set’   source ’VENUS’   nodop   bw=0,0 qual=0  
  noptvlba peak=1 dwell=01:00  /  
  noptvlba peak=1 dwell=01:00  /  
  nopeak ptvlba   dwell = 5:45  /  
  setup=’$SETDIR/pt3mm.set’   nopeak ptvlba dwell = 5:45   /  
 
setup=’$SETDIR/pt90cm.set’  source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt4cm.set’   source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt18cm.set’  source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt6cm.set’   source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt13cm.set’  source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt4cmsx.set’ source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt1cm.set’   source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt24ghz.set’ source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt2cm.set’   source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt7mm.set’   source ’3C273’   nodop   bw=0,0   /  
 
setup=’$SETDIR/pt7mm.set’   source ’WHYA’    doppler bw=2,2 qual=0  
  linename=’SiO431’  
  noptvlba peak=1 dwell=01:00  /  
  noptvlba peak=1 dwell=01:00  /  
  nopeak ptvlba   dwell = 5:45  /  
  setup=’$SETDIR/pt3mm.set’   nopeak ptvlba dwell = 5:45  linename=’SiO862’ /  
setup=’$SETDIR/pt7mm.set’   source ’SATURN’  nodop   bw=0,0 qual=0  
  noptvlba peak=1 dwell=01:00  /  
  noptvlba peak=1 dwell=01:00  /  
  nopeak ptvlba   dwell = 5:45  /  
  setup=’$SETDIR/pt3mm.set’   nopeak ptvlba dwell = 5:45   /  
 
! ---------------------------------------------------------------------  
eofs  
 
#  Now make a file with the actual schedule info for sites without 3mm.  
#  Any imbedded catalogs etc must be here.  
 
cat <<eofs >! ptg_no3mm.par  
! -----  Spectral lines  
! -----  Set up for 4 channels - 2 on line, 2 off.  
lineinit /  
 lineset =’H2O’    restfreq=22235.08,22235.08,22285.08,22285.08 /  
 lineset =’SiO431’ restfreq=43122.03,43122.03,43222.03,43222.03 /  
 lineset =’SiO862’ restfreq=86243.4, 86243.4, 86243.4, 86243.4  /  
endlines /  
 
! -----  The detailed schedule  
! The frequencies are in an order reasonable for FRM.  
!  50/90 cm  CYGA,    TAUA,    3C274  
!  20-4 cm   3C454.3, 3C123,   3C274  
!  2, 1 cm   DR21,    3C84,    3C274  
!  7 mm      RCAS,    RLEO,    WHYA, DR21, 3C84, 3C273, planets  
!  Group must equal the number of scans below.  
!  (Group*rep) must be less than 2000 (as of 18 Apr 1996).  
!  The 7mm line sources used to have qual=50.  This used to be the way  
!     to trigger line processing.  Now CALCODE=’L’ does it.  
 
linename=’SiO431’  
 
group=(12*3) rep=60  
setup=’$SETDIR/pt90cm.set’  source ’CYGA’    nodop   bw=0,0   /  
setup=’$SETDIR/pt4cm.set’   source ’3C454.3’ nodop   bw=0,0   /  
setup=’$SETDIR/pt18cm.set’  source ’3C454.3’ nodop   bw=0,0   /  
setup=’$SETDIR/pt6cm.set’   source ’3C454.3’ nodop   bw=0,0   /  
setup=’$SETDIR/pt13cm.set’  source ’3C454.3’ nodop   bw=0,0   /  
setup=’$SETDIR/pt4cmsx.set’ source ’3C454.3’ nodop   bw=0,0   /  
setup=’$SETDIR/pt1cm.set’   source ’DR21’    nodop   bw=0,0   /  
setup=’$SETDIR/pt24ghz.set’ source ’DR21’   nodop   bw=0,0   /  
setup=’$SETDIR/pt2cm.set’   source ’DR21’    nodop   bw=0,0   /  
setup=’$SETDIR/pt7mm.set’   source ’DR21’    nodop   bw=0,0   /  
setup=’$SETDIR/pt7mm.set’   source ’RCAS’    doppler bw=2,2 qual=0 /  
setup=’$SETDIR/pt7mm.set’   source ’JUPITER’ nodop   bw=0,0 qual=0 /  
 
setup=’$SETDIR/pt90cm.set’  source ’TAUA’    nodop   bw=0,0   /  
setup=’$SETDIR/pt4cm.set’   source ’3C123’   nodop   bw=0,0   /  
setup=’$SETDIR/pt18cm.set’  source ’3C123’   nodop   bw=0,0   /  
setup=’$SETDIR/pt6cm.set’   source ’3C123’   nodop   bw=0,0   /  
setup=’$SETDIR/pt13cm.set’  source ’3C123’   nodop   bw=0,0   /  
setup=’$SETDIR/pt4cmsx.set’ source ’3C123’   nodop   bw=0,0   /  
setup=’$SETDIR/pt1cm.set’   source ’3C84’    nodop   bw=0,0   /  
setup=’$SETDIR/pt24ghz.set’ source ’3C84’   nodop   bw=0,0   /  
setup=’$SETDIR/pt2cm.set’   source ’3C84’    nodop   bw=0,0   /  
setup=’$SETDIR/pt7mm.set’   source ’3C84’    nodop   bw=0,0   /  
setup=’$SETDIR/pt7mm.set’   source ’RLEO’    doppler bw=2,2 qual=0 /  
setup=’$SETDIR/pt7mm.set’   source ’VENUS’   nodop   bw=0,0 qual=0 /  
 
setup=’$SETDIR/pt90cm.set’  source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt4cm.set’   source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt18cm.set’  source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt6cm.set’   source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt13cm.set’  source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt4cmsx.set’ source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt1cm.set’   source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt24ghz.set’ source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt2cm.set’   source ’3C274’   nodop   bw=0,0   /  
setup=’$SETDIR/pt7mm.set’   source ’3C273’   nodop   bw=0,0   /  
setup=’$SETDIR/pt7mm.set’   source ’WHYA’    doppler bw=2,2 qual=0 /  
setup=’$SETDIR/pt7mm.set’   source ’SATURN’  nodop   bw=0,0 qual=0 /  
! ---------------------------------------------------------------------  
eofs  
 
#  
# Now run sched separately for each 3mm station.  
#  
foreach station ( $stalist_3mm[1*] )  
   echo station=vlba_$station >! station.par  
   echo expcode=$expcode >> station.par  
   $SCHED/bin/sched <<eofst  
       @times.par  
       @station.par  
       @ptg_setup.par  
       sch = ptg_3mm.par  
       overwrit /  
eofst  
#  
#  Make the sum and vex files station dependent.  
#  
   /bin/mv ptg.sum ptg.$station.sum  
   /bin/mv ptg.vex ptg.$station.vex  
end  
#  
# Finally run sched separately for each no 3mm station.  
#  
foreach station ( $stalist_no3mm[1*] )  
   echo station=vlba_$station >! station.par  
   echo expcode=$expcode >> station.par  
   $SCHED/bin/sched <<eofst  
       @times.par  
       @station.par  
       @ptg_setup.par  
       sch = ptg_no3mm.par  
       overwrit /  
eofst  
#  
#  Make the sum and vex files station dependent.  
#  
   /bin/mv $expcode.sum $expcode.$station.sum  
   /bin/mv $expcode.vex $expcode.$station.vex  
end  
#  
#   Some clean up.  
#  
#/bin/rm times.par  
#/bin/rm ptg_setup.par  
#/bin/rm ptg_3mm.par  
#/bin/rm ptg_no3mm.par  
#/bin/rm station.par  
#  
#   END